do#puyo_aGameLikeTetris(
	list#globalVars(
		0#playerSquare
		0#playerVerticalNotHorizontal
		3.999#blockLimit
	)
	list#theMousePanels(
		'these 4 mousepanels are the controls for the game. move the mouse in and out of them.'
		mousePanel#leftMousePanel(0 0 0 0 0)
		mousePanel#rightMousePanel(0 0 0 0 0)
		mousePanel#topMousePanel(0 0 0 0 0)
		mousePanel#bottomMousePanel(0 0 0 0 0)
	)
	'squares is the grid of squares the game is played on'
	squares#sq(
		list#theSquares('click' 'new' 'game' a b c d e f)
		6#squaresWide
	)	
	'the right column is 0, and if there are X columns then the left column is X-1'
	%#playerIsInWhichColumn(playerSquare squaresWide)	
	list#groupsOfBlocks(
		list#blockTypes(
			image('red.jpg')
			image('blue.jpg')
			image('yellow.jpg')
			image('green.jpg')
			image('black.jpg')
		)
		list#rareBlocks(
			button#deleteAllRedSquares(
				method#codesimian.PuyoGame.changeAllOfOneFileNameToAnOther(0 0 theSquares 'red.jpg' 'black.jpg')
			)
			mousePanel(.45#mousePanelBlockX .5)
		)
		theSquares
	)
	int#dropFromWhichColumn(*(mousePanelBlockX -(squaresWide 1.0000000001)))
	do#functions(
		func#putRandomBlockSomewhere(
			0#putRandomBlockInThisIndex
			do(
				list(new#newRBS(0 0))
				copyParamToParam(newRBS 1 blockTypes rr(0 blockLimit))
				newRBS
				copyParamToParam(theSquares putRandomBlockInThisIndex newRBS 0)
			)
		)
		'moves a square from one index to an other, and leaves black.jpg in the old square'
		func#moveSquare(
			0#toIndex 0#fromIndex
			do(
				list#temp
				copyParamToParam(temp 0 theSquares fromIndex)
				new#newempty(0 image('black.jpg'))
				copyParamToParam(
					setP#setpe(theSquares fromIndex 0) 2
					newempty 0
				)
				setpe
				copyParamToParam(theSquares toIndex temp 0)
			)
		)
		'do 2 squares have the same filename?'
		func#squaresSameColor(
			0#firstSquareIndex 0#secondSquareIndex
			do(
				recurseP#getstr1(0 theSquares firstSquareIndex 0#indexOfStringInFirstSquare)
				recurseP#getstr2(0 theSquares secondSquareIndex 0#indexOfStringInSecondSquare)
				copyParamToParam( method#java.lang.String.equalsIgnoreCase(0 0 0) 1 getstr1 0)
				copyParamToParam( java.lang.String.equalsIgnoreCase 2 getstr2 0)
				printCode(java.lang.String.equalsIgnoreCase)
				java.lang.String.equalsIgnoreCase
			)
		)
		'the difference between squares is judged by the string in the square: square.P(0).L(String.class)'
		func#squareHasFileName(
			0#indexOfTheSquare 0#doesTheSquareHaveThisFileName
			do(
				recurseP#getstr3(0 theSquares indexOfTheSquare 0)
				copyParamToParam( java.lang.String.equalsIgnoreCase 1 getstr3 0 )
				setP( java.lang.String.equalsIgnoreCase 2 doesTheSquareHaveThisFileName )
				java.lang.String.equalsIgnoreCase
			)
		)
		'does a square with specified index fall or is it on top of something?'
		func#falls(
			0#indexOfSquareThatMightFall
			and(
				>I(indexOfSquareThatMightFall -(squaresWide 1))
				do#emptySquareIsBelow(
					setP(squareHasFileName 0 -(indexOfSquareThatMightFall squaresWide))
					setP(squareHasFileName 1 'black.jpg')
					=Z(0#emptySquareIsBelow squareHasFileName)
					indexOfSquareThatMightFall
					setP(squareHasFileName 0 indexOfSquareThatMightFall)
					=Z(0#emptySquareIsHere squareHasFileName)
					and(emptySquareIsBelow not(emptySquareIsHere))
				)
			)
		)
	)
	list#dontExecuteThisStuffYet(
		button#update(sq)
		button#dropARareBlock(
			if(
				<I(0 countP(rareBlocks))
				do(
					rr#inSecondRowFromTop(  -(countP(theSquares) squaresWide)  -(countP(theSquares) squaresWide squaresWide) )
					=I( 0#rbindex %#rareBlockIndex(count countP(rareBlocks)) )
					copyParamToParam(  theSquares inSecondRowFromTop  rareBlocks rareBlockIndex  )
					'each block in rareBlocks should be used ONCE then removed from rareBlocks'
					deleteP(rareBlocks rbindex)
					1
				)
				0
			)
		)
		button#addToNewSquares(do(
			list(new#newBlock(0 0))
			copyParamToParam(newBlock 1 blockTypes rr(0 blockLimit))
			newBlock
			copyParamToParam(theSquares countP(theSquares) newBlock 0)
		))
		button#help(do(
			window(textarea#textAboutHelp 600 500)
			print(
				'To move the falling piece left,
				move the mouse into the left mousePanel
				with the crosshairs then back out of the mousePanel.
				
				It doesnt matter where the mouse is in the mousePanel,
				only that its inside or outside its rectangle.
				Put the mouse in, out, in, out, in, out
				to move the falling piece over 3 squares.
				
				Use the right mousePanel to move right.
				
				The top mousePanel rotates the falling piece.
				
				The bottom mousePanel moves the pieces down faster.
				
				When you click start_game, the slidebars position sets the game speed,
				but you cant change game speed after that.
				
				Sometimes buttons, slidebars, or other random things fall with the blocks.
				Click them or change them with the mouse to make weird things happen in the game.
				
				It takes 4 blocks the same color to make blocks disappear,
				but it takes at least 5 to get these weird blocks.'
				textAboutHelp
			)
		))
		button#fixPlayerSquare(do(
			=Z(playerVerticalNotHorizontal 0)
			=I(playerSquare -(countP(theSquares) dropFromWhichColumn 1))
			setP(squareHasFileName 0 playerSquare)
			setP(squareHasFileName 1 'black.jpg')
			if(
				not(squareHasFileName)
				do(
					ask$1('Game Over' 'OK')
					method#java.awt.Component.setVisible(0 game 0)
				)
			)
			setP(putRandomBlockSomewhere 0 playerSquare)
			putRandomBlockSomewhere
			setP(putRandomBlockSomewhere 0 +(playerSquare 1))
			putRandomBlockSomewhere
		))
		button#down(do(
			if( <I#alreadyFixedPlayerSquare(playerSquare squaresWide) fixPlayerSquare )
			for(
				0#i
				-(countP(theSquares) squaresWide)
				if(
					do#shouldTheSquareFall(setP(falls 0 +(i squaresWide)) falls)
					do(
						if#movePlayerSquarePointerDown1Square(
							==I(+(i squaresWide) playerSquare)
							=I(playerSquare i)
						)
						'need to check if +(i squaresWide) == playerSquare'
						setP(moveSquare 0 i)
						setP(moveSquare 1 +(i squaresWide))
						moveSquare
					)
					if(
						not(alreadyFixedPlayerSquare)
						if#playerSquareLanded(
							==I(+(i squaresWide) playerSquare)
							fixPlayerSquare
						)
					)
				)
			)
			setP(squareHasFileName 0 playerSquare)
			setP(squareHasFileName 1 'black.jpg')
			if(squareHasFileName fixPlayerSquare)
		))
		button#code_of_this_game(
			window#execute_code_by_right_clicking_it(puyo_aGameLikeTetris)
		)
		button#printTheSquares(do(
			print(' ++++++++++++++THESQUARES:++++ ')
			printCode(theSquares)
		))
		button#testColor(do(
			setP(squaresSameColor 0 0)
			setP(squaresSameColor 1 1)						
			printD(squaresSameColor)
		))
		button#testFileName(do(
			setP(squareHasFileName 0 0)
			setP(squareHasFileName 1 'knight.jpg')
			print('       testFileName  square=0  filename=')
			recurseP#rprp(0 theSquares 0 0)
			copyParamToParam(printCode#psps 0 rprp 0)
			psps
			print('   it had that name = ')
			printD(squareHasFileName)
			print('   java.lang.String.equalsIgnoreCase = ')
			printCode(java.lang.String.equalsIgnoreCase)
		))
		button#rotatePlayer(
			if(
				and(
					<I( playerSquare -(countP(theSquares) squaresWide) )
					or(
						playerVerticalNotHorizontal
						<I(playerIsInWhichColumn -(squaresWide 1))
					)
				)
				do(
					=Z(playerVerticalNotHorizontal not(playerVerticalNotHorizontal))
					=D(0#verticalSquare +(playerSquare squaresWide))
					=D(0#horizontalSquare +(playerSquare 1))
					if(
						playerVerticalNotHorizontal
						do#moveSquareFromHorizontalToVertical(
							setP(moveSquare 0 verticalSquare)
							setP(moveSquare 1 playerSquare)
							moveSquare
							setP(moveSquare 0 playerSquare)
							setP(moveSquare 1 horizontalSquare)
							moveSquare
						)
						do#moveSquareFromVerticalToHorizontal(
							setP(moveSquare 0 horizontalSquare)
							setP(moveSquare 1 playerSquare)
							moveSquare
							setP(moveSquare 0 playerSquare)
							setP(moveSquare 1 verticalSquare)
							moveSquare
						)
					)
					sq
				)
			)
		)
		button#exit(method#java.lang.System.exit(0 0 0))
		button#deleteSquares(
			repeat(
				6
				do(
					method#codesimian.PuyoGame.biggestGroupOfSquares(0 0 theSquares squaresWide 'black.jpg')
					copyParamToParam(
						countP#deleteHowManySquares 0
						codesimian.PuyoGame.biggestGroupOfSquares 0
					)
					for(
						0#d
						deleteHowManySquares
						do(
							new#newempty2(0 image('black.jpg'))
							copyParamToParam(
								theSquares recursePD(0 codesimian.PuyoGame.biggestGroupOfSquares 0 d)
								newempty2 0
							)
						)
					)
					if(
						<I(5 deleteHowManySquares)
						do(
							print("   dropping a rare block...  deleteHowManySquares=")
							printD(deleteHowManySquares)
							dropARareBlock
							print("      deleted this many squares: ")
							printD(deleteHowManySquares)
							print("   codesimian.PuyoGame.biggestGroupOfSquares = ")
							printCode(codesimian.PuyoGame.biggestGroupOfSquares)
						)
					)
				)
			)
		)
		slidebar#gameSpeedSlidebar(.3)
		button#start_game(do(
			new#copyTheTimerBecauseTimerOnlyWorksOnce(
				0
				timer( do(down update deleteSquares) ^(.03 gameSpeedSlidebar) 1000 )
			)
			execParam#startTheTimer(copyTheTimerBecauseTimerOnlyWorksOnce 0)
		))
		button#new_game(do(
			staticrepeat(countP(theSquares) deleteP(theSquares 0))
			6#startSquareQuantity
			staticrepeat(startSquareQuantity addToNewSquares)
			repeat(
				-(72 startSquareQuantity)
				do(
					new#newEmptyBlock(0 image('black.jpg'))
					copyParamToParam(theSquares countP(theSquares) newEmptyBlock 0)
				)
			)
		))
		button#adjacentSquares(do(
			method#codesimian.PuyoGame.getAdjacentSquares(
				0 0
				countP(theSquares) squaresWide 6
			)						
			copyParamToParam(
				printCode#printAdjacentSquares 0
				codesimian.PuyoGame.getAdjacentSquares 0
			)
			printAdjacentSquares
		))
		button#Up(do(
			setP(moveSquare	0 +(playerSquare squaresWide))
			setP(moveSquare	1 playerSquare)
			moveSquare
			=I(playerSquare +(playerSquare squaresWide))
			sq
		))
		button#Down(do(
			setP(moveSquare	0 -(playerSquare squaresWide))
			setP(moveSquare	1 playerSquare)
			moveSquare
			=I(playerSquare -(playerSquare squaresWide))
			sq
		))
		topMousePanel
		button#Move_Left(do(
			do(
				setP(squareHasFileName 0 +#psplus1(playerSquare 1))
				setP(squareHasFileName 1 'black.jpg')
				=Z(0#leftSquareIsEmpty squareHasFileName)
				print('        squareHasFileName() = ')
				printD(squareHasFileName)
				print('        ')
				setP(falls 0 psplus1)
				=Z(0#leftSquareFalls falls)
			)
			if(
				and(
					not(playerVerticalNotHorizontal)
					leftSquareFalls
					<I(playerIsInWhichColumn -(squaresWide 2))
					do#square2LeftOfPlayerIsEmpty(
						setP(squareHasFileName 0 +(playerSquare 2))
						squareHasFileName
					)
				)
				do#moveBothSquaresLeft(
					setP(moveSquare	0 +(playerSquare 2))
					setP(moveSquare	1 psplus1)
					moveSquare
					setP(moveSquare	0 psplus1)
					setP(moveSquare	1 playerSquare)
					moveSquare
					=I(playerSquare psplus1)
					sq
				)
			)
			if(
				and(
					leftSquareIsEmpty
					<I(playerIsInWhichColumn -(squaresWide 1))
				)
				do#dontMoveSquareLeftOfPlayer(
					setP(moveSquare	0 psplus1)
					setP(moveSquare	1 playerSquare)
					moveSquare
					if(
						playerVerticalNotHorizontal
						if(
							<I(playerSquare -(countP(theSquares) squaresWide))
							do(
								setP(moveSquare	0 +(playerSquare squaresWide 1))
								setP(moveSquare	1 +(playerSquare squaresWide))
								moveSquare
							)
						)
					)
					=I(playerSquare psplus1)
					sq
				)
			)
		))
		leftMousePanel
		sq
		rightMousePanel
		button#Move_Right(
			if(
				do(
					setP(squareHasFileName 0 -#psminus1(playerSquare 1))
					setP(squareHasFileName 1 'black.jpg')
					and(
						squareHasFileName
						<I( 0 playerIsInWhichColumn )
					)
				)
				do(
					setP(moveSquare	0 psminus1)
					setP(moveSquare	1 playerSquare)
					moveSquare
					if(
						playerVerticalNotHorizontal
						if(
							<I(playerSquare -(countP(theSquares) squaresWide))
							do(
								setP(moveSquare	0 +(playerSquare squaresWide -1))
								setP(moveSquare	1 +(playerSquare squaresWide))
								moveSquare
							)
						)
						do(
							setP(falls 0 psplus1)
							if(
								falls
								do(
									setP(moveSquare	0 playerSquare)
									setP(moveSquare	1 psplus1)
									moveSquare
								)
							)
						)
					)
					=I(playerSquare psminus1)
					sq
				)
				print('  cant go right')
			)
		)
		'this is the end of a very long list(...)'
	)
	
	'connect the on-screen controls to the actions they should do'
	do(
		setP( leftMousePanel 5 do(print(' moving left') Move_Left) )
		setP( rightMousePanel 5 do(print(' moving left') Move_Right) )
		setP( topMousePanel 5 do(print(' top mouse panel') rotatePlayer) )
		setP( bottomMousePanel 5 do(print(' bottom mouse panel') down sq) )
	)
	
	'the main window'
	window#game(
		splitPane(
			horizontal#buttonsTopRow(
				start_game
				gameSpeedSlidebar
				help
				exit
			)
			splitPane#lowestSplit(
				topMousePanel
				splitPane#lowestLowestSplit(
					horizontal(
						leftMousePanel
						sq
						rightMousePanel
					)
					horizontal(
						button#buttons_for_testing(
							window#used_these_buttons_while_building_the_game(
								splitPane(
									horizontal(
										update
										addToNewSquares
										dropARareBlock
										down
										printTheSquares
										testColor
										testFileName
										new_game
									)
									horizontal(
										deleteSquares
										adjacentSquares
										rotatePlayer
										Up
										Down
										Move_Left
										Move_Right
									)
								)
								800 100
							)
						)
						bottomMousePanel
						code_of_this_game
					)
					1.33
				)
			)
		)
		530 570
	)
	
	setP(java.awt.Component.setVisible 1 game)	
	
	'display the game board for the first time'
	new_game
	fixPlayerSquare
	update
	
	'fix splitPane sizes'
	setP(lowestLowestSplit 2 1.8)
	lowestLowestSplit
	setP(lowestSplit 2 1.15)
	lowestSplit
		
)